;hnCOcaNH.gjr-1
;avance-version
;3D HNN (800 MHz)
;o2p = 56.0 ppm
;Panchal et el J Biomol NMR 20, 135, 2001
;Chugh J et al J Biomol NMR 40(2), 145-152
;1) exclude Rance-Kay trick
;2) use maximum resolution for t2 including also period k
;3) water flip back and final watergate for water suppression

;sequence checkd and corrected by DMO

;written by dk at 800 MHz

;$OWNER=guest
prosol relations =<triple>

#include <Avance.incl>
#include <Grad.incl>
#include <Delay.incl>



;############### constant values ##############
"d2=2.4m"
"d5=2.4m-p11-3u-4u-p16-d16"         
"d6=5.4m"                           ;k
"d11=30m"
"d14=p14"
"d16=120u"
"p28=1000u" ;for watergate block
"p11=1000u" ;for water flip back pulses
"d7=12m"
"p2=p1*2"
"p22=p21*2"
"p34=200u"
"p40=800u"
"p26=40u"
;############### center pulses ################
"d3=p21-p1"
"d8=(p14-p21*2)*0.5"
"d27=d7-d6-p26-20u"
;############### incremented time t1 ##########
"d0=3u"                             ;t1/2
"d9=d0+d14+d7+d8"                    ;t1/2 NOTE that d9<=d8+3u
"d21=d0+d14+d7+d8+p22+d8+d9-d6-p26-4u"
;############### incremented time t2 ##########

"d10=3u"                            ;t2/2 increased
;############### Ca-Co ##########
"d22=4.1m-p14-4u"                    ; half of the evolution time of Ca CO (4.5ms) 
"d15=12.5m"
"d24=d15-d22"

"in9=in0"

"DELTA3=d10*2+larger(p14,p22)-p14"

"spoff2=bf2*(cnst22/1000000)-o2"                          ; 90 degree shaped on CA, Q5.1000
"spoff3=bf2*(cnst22/1000000)-o2"                          ; 180 degree shaped on CA, Q3.1000
"spoff8=bf2*(cnst22/1000000)-o2"                          ; 90 degree shaped on CA, Q5tr.1000
"spoff20=bf2*(cnst33/1000000)-o2"                         ; 180 degree shaped on CA, Q3.1000

"spoff5=0"    ; 180 degree shaped on CO, Q3.1000
"spoff4=0"    ; 90 degree shaped on CO, Q5.1000
"spoff6=0"    ; 90 degree shaped on CO, Q5tr.1000


aqseq 312

1 ze
2 d11 do:f3
3 d1 pl1:f1 
  4u pl3:f3
  50u UNBLKGRAD
  (p1 ph0)
  d2 pl3:f3
  (center (p2 ph0) (p22 ph0):f3 )
  d2
  (p1 ph9):f1
  4u pl0:f1
  (p11:sp1 ph7:r):f1
  4u 
  p16:gp1
  d16 pl19:f1
  (p21 ph1):f3

;#### Start t1 d0=A ; d7=15m=B ; d9=C=15m-3u ; d6=5.4m=k #########
(d6 p26 ph9 20u cpds1):f1 
d27 
(center (p14:sp5 ph0):f2 (p22 ph0):f3 )
d7
;########### end t1 ############

  (p21 ph2):f3
  4u do:f1
(p26 ph10):f1
4u
  p16:gp2*-1
 d16 pl19:f1
  (p26 ph9 20u cpds1):f1 
; magnetization on CO
(p13:sp4 ph3):f2
4u
(p14:sp3 ph0):f2
d22 
(p14:sp5 ph0):f2
4u
(p14:sp3 ph0):f2
d22 
d10
(center (p14:sp3 ph0):f2 (p22 ph0):f3)
d10
4u
  (p14:sp3 ph0):f2
  DELTA3
  (p14:sp5 ph0):f2
4u
(p13:sp6 ph9):f2
; C' to Ca transfer
 4u do:f1
 (p26 ph10):f1
 p16:gp7*-1
 d16 pl19:f1
 (p26 ph9 20u cpds1):f1 
; magnetization on Ca 
(p13:sp2 ph0):f2
d22
(p14:sp5 ph0):f2
4u
(p14:sp3 ph0):f2
d22
(p14:sp5 ph0):f2
4u 
d15
 (center (p14:sp3 ph0):f2 (p22 ph0):f3)
 d15
 (p13:sp8 ph9):f2
  4u do:f1
 (p26 ph10):f1  
  4u
  p16:gp3
  d16 pl19:f1
  (p26 ph9 4u cpds1):f1
; Magnetization is on N
  (p21 ph8):f3
  5u
;#### Start t2 d10=F ; d20=D=15m-3u ; d7=E=15m ; d6=5.4m=k #########
  
(d21 4u do p26 ph10):f1 (d0 p14:sp5 ph0 d7 p14:sp3 ph0 d9):f2 (d0 d14 d7 d8 p22 ph6 d8 d9):f3

  
;######## end t2 ##############

 (p21 ph0):f3
  4u
  p16:gp5
  d16 pl0:f1
  (p11:sp1 ph5:r):f1
  10u
  20u pl1:f1
  (p1 ph0):f1
  3u
  p40:gp4
  d16
  4u
  d5 pl0:f1                          
  (p28:sp11 ph4:r):f1
  3u
  20u pl1:f1
  (center (p1*2 ph5) (p21*2 ph0):f3)
  3u
  20u pl0:f1
 (p28:sp11 ph4:r):f1
  3u
  d5                                  
  p40:gp4
  d16 pl16:f3
  4u BLKGRAD
  go=2 ph31 cpd3:f3
  d11 do:f3 mc #0 to 2
  
  F1PH(ip8, id0 & dd9)
  F2PH(rd0 & rd9 & ip3, id10)
exit

ph0=0
ph1=2 2 0 0
ph2=0 2 2 0
ph3=0 2 2 0
ph4=0
ph5=2
ph7=0
ph8=0
ph6=0 0 0 0 2 2 2 2
ph9=1
ph10=3
ph31=0 0 2 2


;d1: relaxation delay; 1-5*T1
;d11: delay for disk I/O [30 msec]
;pl1: f1 power H high power pulse
;p1: f1 90 degree high power pl1 pulse
;d2: 2.25-2.75m (Jhn=92Hz)
;d3: p21-p1 (center pulse)
;pl2: f2 power C13 hard pulse (not used)
;pl3: f3 power N15 hard pulse
;p21: f3 90 degree high power N15 high power pl3 pulse
;pl11: f1 power H2O soft rectangular pulse (1m)
;p11: f1 90 degree H2O low power pl11 rectangluar pulse
;p13: 90 degree 13C shape
;p14: 180 degree 13C shape
;d6: 5.4m (k in sequence)
;pl19: f1 power for cpds1 decoupling
;cpd1: dipsi2 (along x)
;pcpd3: f1 cpds1 pulse length (60-70u) use 65u
;d0: t1/2
;d7: Tn [12-16m] use 15m
;d9: d0+d14+d7+d8 (Tn-t1/2) SET ALWAYS d9<=d8+3u
;d15: [12-18m] Tcn, use 16m
;d20: t2/2 (Tn-t2/2) [d9-d8]
;d10: t2/2
;cnst19: CO offset in ppm
;cnst33: CA offset for alanine or S/T check points
;cnst33: offset of pulse for CA and CO decoupling 110 ppm
;gpz3: 30%
;gpnam3: sine.100 shape of gradient pulse
;gpz1: 30%
;gpnam1: sine.100 shape of gradient pulse
;gpz2: 30 %
;gpnam2: sine.100 shape of gradient pulse
;p16: gradient pulse 1 ms
;p40: gradient pulse 0.5 ms
;p35: gradient pulse 0.5 ms
;gpz4: 80 %
;gpnam4: sine.100 shape of gradient pulse
;gpz5: 50%
;gpnam5: sine.100 shape of gradient pulse
;gpz6: 20%
;gpnam6: sine.100 shape of gradient pulse
;gpz7: 60%
;gpnam7: sine.100 shape of gradient pulse
;p14: f2 soft shaped pulse 180 null at 18200 Hz
;sp5: f2 power 180 (CA) soft shaped
;spnam5: use shape Q3.1000
;spoff5: use offset 176 ppm on CO, null CA
;sp6: f2 power 180 (CO) soft shaped
;spnam6: use shape Q5tr.1000
;spoff6: use offset at 176 ppm (700 MHz) on CO, null CA
;sp8: f2 power 180 (CA) soft shaped
;spnam8: use shape Q5tr.1000
;spoff8: use offset at 56 ppm on CA, null CO
;spnam3: use shape Q3.1000
;spoff3: use offset 56 ppm on CA, null CO
;sp2: f2 power 90 (CA) soft shaped
;spnam2: use shape Q5.1000
;spoff2: use offset 0.0 on CA, null CO
;sp4: f2 power 90 (CA) soft shaped
;spnam4: use shape Q5.1000 
;spoff4: use offset 0.0 on CA, null CO
;sp1: f1 power H2O soft shaped pulse
;p11: (2m) half-gaussian soft pulse with power sp1
;spnam1: hg.1000 half gaussian shape
;p34: 200-400-600us, f2 180 degree 13C shape
;sp20: f2 power 180 (CA)
;spnam20: Q3 gauss works fine
;spoffs20: 56ppm for HNN and HNN-Ala and 64ppm for HNN-ST

;d4: 2.7m-p2-3u-4u-p16-d16
;pl16: f3 power level N15 cpd decoupling
;cpd3: cpdprg3 decoupling sequence [garp]
;pcpd3: f3 decoupling 90 degree pulse [>170 u]
;l1: td1/2 STATES/TPPI
;l2: td2/2 STATES/TPPI
;in0: 1/(2* SW(N15)) = DW(N15)
;in10: 1/(2* SW(C13)) = DW(C13)
;in9: SET ALWAYS in9=in0
;nd0: 2
;nd10: 2
;NS: 8*n
;DS: 16
;td1: number of experiments N15
;td2: number of experiments N15
;MC2: STATES-TPPI